Le forum du Master ESA économétrie et statistique appliquée - Université d'Orléans / macro variables au niveau de datalines statement

nizarcom · 13-01-2010 11:57:28

Bjr tt le monde,

plz essayer de m'aider pour résoudre un porblème qui se rapporte à l'utilisation des macro variables, au niveau de l'etape datalines.

J'ai essayer de trouver des informations sur internet mais j'ai rien trouvé.

ma question est pourquoi le code suivant ne marche pas .

%let t1 = cfg25 ;
%let t2 = iam ;
%let t3 = adh ;

data Inst_Data_wo;
input InstType $ InstID $ Company $ ;
Mkt_P = ("P_" || InstID);
datalines ;
Stk &t1 &t1
Stk &t2 &t2
Stk &t3 &t3
;
run ;

Alors que le résultat est :

Obs InstType InstID Company Mkt_P
1 Stk &t1 &t1 P_&t1
2 Stk &t2 &t2 P_&t2
3 Stk &t3 &t3 P_&t3

jabdeltif · 13-01-2010 19:57:33

Bonjour,

Si ma mémoire est bonne, une macro variable globale est utilisable partout dans un code lors de la session SAS dans lequel la macro variable a été créée sauf dans datalines ou déclarations CARDS.
Mais, avec SAS il y a toujours une alternative...! Et c'est ça qui est bon ;-)

Cordialement

A.J

alaa-eddine · 13-01-2010 23:26:59

On aimerait bien savoir quelle est la finalité de votre démarche, qu'allez vous faire de cette table ? Par exemple... est ce que vous vous arrêtez à 3 macros variables ?... ou ce programme va être généralisé à plusieurs macros variables ?...etc
, cela pourrais nous aider à vous proposer la solution la plus adéquate, parce que là il est claire que des macros variables dans un cards ou un datalines, ça ne marche pas !!! Et il est normal que vous ne trouviez rien sur internet...

Cela dit, si vous tenez à vos 3 macros variables vous pouvez utiliser cette alternative, en passant en SQL :

Code:

%let t1 = cfg25 ;
%let t2 = iam ;
%let t3 = adh ;

proc sql;

   create table Inst_Data_wo
       (InstType char(6),
        InstID char(6),
        Company char(6),
        Mkt_P char(8));

  insert into bidon
    values('Stk',"&t1","&t1","P_&t1")
    values('Stk',"&t2","&t2","P_&t2")
    values('Stk',"&t3","&t3","P_&t3");

 quit;

Mais dites donc, iam(Itissalat Al Maghrib) cfg25(Group cfg) adh(Douja Prom Addoha)... c'est pour une Opcvm ça ? Vous bossez pour qu'elle boîte au Maroc ?
Qui c'est qui utilise SAS de la sorte?... qu'on vienne vous donner un p’tit coup de main

A+

Et bonne année aux gens d'Orléans ! (on a encore le droit de le dire jusqu'à la fin du mois)

esa_sr · 14-01-2010 08:34:10

et oui, vous ne pouvez pas avoir des appels à macro variables dans les zones cards / datalines : le processeur macro ne va pas interpréter ce qui peut passer par "l'input buffer".

Alaa Eddine vous a donner une solution SQL - il est aussi possible de construire votre table avec une étape DATA de la manière suivante :

Code:

%let t1 = cfg25 ;
%let t2 = iam ;
%let t3 = adh ;

data Inst_Data_wo (drop=i);
do i=1 to 3;
   InsType="Stk";
   InstID=symget('t'!!left(put(i,2.)));
   Company=instid;
   Mkt_P = ("P_" || InstID);
   output;
end;
run;

proc print;run;

le principe de SYMGET est expliqué dans cet excellent livre qu'il faudra bien un jour vous procurer... ;-)

et comme le dit Jabdeltif,

avec SAS il y a toujours une alternative...! Et c'est ça qui est bon ;-)

AHOYO · 14-01-2010 10:02:19

Une autre astuce très simple pour avoir tes résultats:

%let t1 = cfg25 ;
%let t2 = iam ;
%let t3 = adh ;

data Inst_Data_wo;
input InstType $ InstID $ Company $ ;
InstID= resolve(InstID);
Company= resolve(Company);
Mkt_P = ("P_" || InstID);
datalines ;
Stk &t1 &t1
Stk &t2 &t2
Stk &t3 &t3
;run ;
proc print ; run;

esa_sr · 14-01-2010 10:09:29

et comme le dit Jabdeltif,

avec SAS il y a toujours une alternative...! Et c'est ça qui est bon ;-)

AHOYO · 14-01-2010 10:34:19

Je suis tout à fait d'accord!!!!!!

nizarcom · 14-01-2010 10:55:16

Merci à vous pour votre collaboration
Pour répondre à la question de monsieur alla eddine ;

Je vous dis que je suis en période de stage de fin d’études, que je suis entrain de le passer dans une banque d’affaire, donc je travaille sur un projet de Risk Management et plus précisément pour la modélisation du Risque de marché.
Ce que j’ai réussi à faire, sous SAS, jusqu’à présent c’est de calculer la value at risk avec deux approches : selon la simulation historique, et suivant la simulation MC de la matrice de variance covariance,
Mon objectif principal c’est d’automatiser la majorité des taches de telle manière que :une fois on donne à la moulinette SAS un portefeuille il nous calculera la VaR des valeurs composant le portefeuille, et la VaR totale (bien qu’il ya le problème d’additivité de la VaR… )

Ça c’est l’objectif, la contrainte c’est que je suis débutant sur l’outil SAS (et surtout le module Risk Dimensions), ce qui me pose beaucoup de problèmes et à partir de là je vous dérange à chaque fois, je vous prie de me pardonner car j’ai le souci de réussir cette expérience.

alaa-eddine · 14-01-2010 19:36:44

Pour une banque d'affaire ?!

- BMCE Capital ??
- Attijari Finance Corp ?? (Je ne pense pas qu'ils ont SAS...)
- CFG ??
- Upline ??
- CDG Capital ?? (SPSS il me semble...)

Vous avez fais quelle école ?

... Si ce n'est pas trop indiscret bien sûr

gang · 14-01-2010 20:28:26

Lol alaa ca va ? t 'es de la police maintenant!!

esa_sr · 14-01-2010 22:02:16

mais non, c'est :

1- qu'il est au bled - p'tet qu'il se sent seul
2- c'est devenu un vrai requin - p'tet qu'il prospecte !

alaa-eddine · 14-01-2010 22:15:54

...

Annonce

#1 13-01-2010 11:57:28

macro variables au niveau de datalines statement

#2 13-01-2010 19:57:33

Re: macro variables au niveau de datalines statement

#3 13-01-2010 23:26:59

Re: macro variables au niveau de datalines statement

Code:

#4 14-01-2010 08:34:10

Re: macro variables au niveau de datalines statement

Code:

#5 14-01-2010 10:02:19

Re: macro variables au niveau de datalines statement

#6 14-01-2010 10:09:29

Re: macro variables au niveau de datalines statement

#7 14-01-2010 10:34:19

Re: macro variables au niveau de datalines statement

#8 14-01-2010 10:55:16

Re: macro variables au niveau de datalines statement

#9 14-01-2010 19:36:44

Re: macro variables au niveau de datalines statement

#10 14-01-2010 20:28:26

Re: macro variables au niveau de datalines statement

#11 14-01-2010 22:02:16

Re: macro variables au niveau de datalines statement

#12 14-01-2010 22:15:54

Re: macro variables au niveau de datalines statement

Pied de page des forums