Le forum du Master ESA économétrie et statistique appliquée - Université d'Orléans

Vous n'êtes pas identifié.

Annonce

Vous êtes sur le forum du master ESA !

Le site du master ESA - description de la formation, notes de cours, contacts... est ici :

http://www.univ-orleans.fr/deg/masters/ESA/

#1 10-03-2007 23:41:26

Kathleen
Member
Lieu: Orleans
Date d'inscription: 09-03-2007
Messages: 12

pourquoi ne puis je pas poster???

coucou!
pourquoi ne puis je pas poster dans la partie infos sur le forum pour mettre une nouvelle discussion par exemple (ya pas l'onglet, le lien comme dans les autres parties) et pourquoi quand je clic sur "amelioration du site" il n'y a rien et si jeclic sur le lien du dernier message j'attéris sur "forum en panne"???!!!etrange etrange big_smile

Hors ligne

 

#2 12-03-2007 10:11:03

esa_sr
Administrator
Date d'inscription: 21-02-2007
Messages: 5795
Site web

Re: pourquoi ne puis je pas poster???

bonjour,
la partie info du forum m'est réservée (rien qu'à moi - je ne souffre pas la contradiction ;-)) - quand au post amélioration du site, effectivement, il y a un bug dans le logiciel - je n'arrive pas pour l'instant à le retirer... si vous souhaitez soumettre des suggestions, vous pouvez les indiquer dans la partie cours de récréation
cordialement
SR

Hors ligne

 

#3 12-03-2007 17:29:32

Kathleen
Member
Lieu: Orleans
Date d'inscription: 09-03-2007
Messages: 12

Re: pourquoi ne puis je pas poster???

Merci smile

Hors ligne

 

#4 16-09-2007 10:23:13

stat_sas
membre extérieur
Date d'inscription: 15-09-2007
Messages: 1

Re: pourquoi ne puis je pas poster???

j'ai galéré pendant mon stage pour faire une comparaison de deux courbes Roc
,alors si ça peut aider quelqu'un:

%macro roc(version, data=, var=, response=, contrast=, details=no,
           alpha=.05);

%let _version=1.6;
%if &version ne %then %put ROC macro Version &_version;

%let opts = %sysfunc(getoption(notes))
            _last_=%sysfunc(getoption(_last_));
options nonotes;

/* Check for newer version */
%if %sysevalf(&sysver >= 8.2) %then %do;
  filename _ver url 'http://ftp.sas.com/techsup/download/stat/versions.dat' termstr=crlf;
  data _null_;
    infile _ver;
    input name:$15. ver;
    if upcase(name)="&sysmacroname" then call symput("_newver",ver);
    run;
  %if &syserr ne 0 %then
    %put ROC: Unable to check for newer version;
  %else %if %sysevalf(&_newver > &_version) %then %do;
    %put ROC: A newer version of the ROC macro is available.;
    %put %str(         ) You can get the newer version at this location:;
    %put %str(         ) http://support.sas.com/ctx/samples/index.jsp;
  %end;
%end;

title "The ROC Macro";
title2 " ";

%let error=0;

/* Verify that DATA= option is specified */
%if &data= %then %do;
    %put ERROR: Specify DATA= containing the OUT= data sets of models to be compared;
    %goto exit;
%end;

/* Verify that VAR= option is specified */
%if &var= %then %do;
    %put ERROR: Specify predictor or XBETA variables in the VAR= argument;
    %goto exit;
%end;

/* Verify that RESPONSE= option is specified */
%if &response= %then %do;
    %put ERROR: Specify response variable in the RESPONSE= argument;
    %goto exit;
%end;

%let i=1;
%do %while (%scan(&data,&i) ne %str() );
  %let data&i=%scan(&data,&i);
  %let i=%eval(&i+1);
%end;
%let ndata=%eval(&i-1);

data _comp(keep = &var &response);
%if &data=%str() or &ndata=1 %then set;
%else merge;
  &data;
  if &response not in (0,1) then call symput('error',1);
  run;
%if &error=1 %then %do;
  %put ERROR: Response must have values 0 or 1 only.;
  %goto exit;
%end;

/* Original SAS/IML code from author follows */
proc iml;
   start mwcomp(psi,z);
    *;
    * program to compute the mann-whitney components  ;
    * z is (nn by 2);
    *  z[,1] is the column of data values;
    *  z[,2] is the column of indicator variables;
    *   z[i,2]=1 if the observation is from the x population;
    *   z[i,2]=0 if the observation is from the y population;
    *
    * psi is the returned vector of u-statistic components;

    rz  = ranktie( z[,1] );                        * average ranks;
    nx  = sum( z[,2] );                            * num. of Xs  ;
    ny  = nrow(z)-nx;                              * num of Ys   ;
    loc = loc( z[,2]=1 );                          * x indexes   ;
    psi = j(nrow(z),1,0);
    psi[loc] = (rz[loc] - ranktie(z[loc,1]))/ny;   * x components ;
    loc = loc( z[,2]=0 );                          * y indexes    ;
    psi[loc] = ( nx+ranktie(z[loc,1])-rz[loc])/nx; * y components ;
    free rz loc nx ny;                             * free space   ;
   finish;

   start mwvar(t,v,nx,ny,z);
    *;
    * compute mann-whitney statistics and variance;
    * input z, n by (k+1);
    *  z[,1:k] are the different variables;
    *  z[,k+1] are indicator values,
    *    1 if the observation is from population x and ;
    *    0 if the observation is from population y;
    * t is the k by k vector of estimated statistics;
    *  the (i,j) entry is the MannWhitney statistic for the
    *  i-th column when used with the j-th column. The only
    *  observations with nonmissing values in each column are
    *  used. The diagonal elements are, hence, based only on the
    *  single column of values.
    * v is the k by k estimated variance matrix;
    * nx is the matrix of x population counts on a pairwise basis;
    * ny is the matrix of y population counts on a pairwise basis;

    k   = ncol(z)-1;
    ind = z[,k+1];
    v   = j(k,k,0); t=v; nx=v; ny=v;

    * The following computes components after pairwise deletion of
    *  observations with missing values. If either there are no missing
    *  values or it is desired to use the components without doing
    *  pairwise deletion first, the nested do loops could be evaded.
    *;
    do i=1 to k;
      do j=1 to i;
         who = loc( (z[,i]^=.)#(z[,j]^=.) );    * nonmissing pairs;
         run mwcomp(psii,(z[,i]||ind)[who,]);   * components;
         run mwcomp(psij,(z[,j]||ind)[who,]);
         inow = ind[who,];                      * Xs and Ys;
         m = inow[+];                           * current Xs;
         n = nrow(psii)-m;                      * current Ys;
         nx[i,j] = m; ny[i,j] = n;
         mi = (psii#inow)[+] / m;               * means;
         mj = (psij#inow)[+] / m;
         t[i,j] = mi; t[j,i] = mj;
         psii = psii-mi; psij = psij-mj;        * center;
         v[i,j] = (psii#psij#inow)[+]     / (m#(m-1))
                + (psii#psij#(1-inow))[+] / (n#(n-1));
         v[j,i] = v[i,j];
      end;
    end;
    free psii psij inow ind who;
   finish;

   /* start of execution of the IML program */
   use _comp var {&var &response};
   read all into data [colname=names];
   run mwvar(t,v,nx,ny,data);                 * estimates and variances;
   vname = names[1:(ncol(names)-1)];
   manwhit = vecdiag(t);

   /* omit: 0 for intercept-only model; not needed for further
      computations
   c=sqrt( vecdiag(v) );  c=v / (c@c`);
   %if %upcase(%substr(&details,1,1)) ne N %then %do;
    print c [label='Estimated Correlations' colname=vname rowname=vname];
   %end;
   */

%if &contrast= %then %do;
  %put ROC: No contrast specified.  Pairwise contrasts of all;
  %put %str(    ) curves will be generated.;
   call symput('col',char(ncol(data)-1));
  %if &col=1 %then %str(l=1wink; %else %do;
   lsadj(&col-1,1)||-i(&col-1))
    %do i=&col-2 %to 1 %by -1;
        //(j(&i,&col-&i-1,0)||j(&i,1)||-i(&i))
    %end;
   ;
   %end;
%end;
%else %do;
   l = { &contrast };
%end;

   lt=l*manwhit;
   lv=l*v*l`;
   c = ginv(lv);
   chisq = lt`*c*lt;
   df = trace(c*lv);
   p = 1 - probchi( chisq, df );
/* Original SAS/IML code by author ends */

   /* Individual area stderrs and CIs */
   stderr=sqrt(vecdiag(v));
   arealcl=manwhit-probit(1-&alpha/2)*stderr;
   areaucl=manwhit+probit(1-&alpha/2)*stderr;
   areastab=putn(manwhit||stderr||arealcl||areaucl,'7.4');

   /* Pairwise difference stderrs and CIs */
   sediff=sqrt(vecdiag(lv));
   difflcl=lt-probit(1-&alpha/2)*sediff;
   diffucl=lt+probit(1-&alpha/2)*sediff;
   diffchi=(lt##2)/vecdiag(lv);
   diffp=1-probchi(diffchi,1);

  %if %upcase(%substr(&details,1,1)) ne N %then %do;
   print t [label='Pairwise Deletion Mann-Whitney Statistics' colname=vname
   rowname=vname];
  %end;

   print areastab [label=
   "ROC Curve Areas and %sysevalf(100*(1-&alpha))% Confidence Intervals"
   rowname=vname colname={'ROC Area' 'Std Error' 'Confidence' 'Limits'}];

   call symput('maxrow',char(comb(max(nrow(l),2),2)));
   rname='Row1':"Row&maxrow";
%if %upcase(%substr(&details,1,1)) ne N %then %do;
   print v [label='Estimated Variance Matrix' colname=vname rowname=vname];
   print nx [label='X populations sample sizes' colname=vname rowname=vname];
   print ny [label='Y populations sample sizes' colname=vname rowname=vname];
   print lv [label='Variance Estimates of Contrast' rowname=rname
             colname=rname];
  %end;
   print l [label='Contrast Coefficients' rowname=rname colname=vname];

   fdiffchi=putn(diffchi,'9.4');
   fdiffp=putn(diffp,'pvalue.');
   diffs=putn(lt||sediff||difflcl||diffucl,'7.4');
   diffstab=diffs||fdiffchi||fdiffp;
   print diffstab [label=
   "Tests and %sysevalf(100*(1-&alpha))% Confidence Intervals for Contrast Rows"
   rowname=rname colname={'Estimate' 'Std Error' 'Confidence' 'Limits'
   'Chi-square' 'Pr > ChiSq'}];

   c2=putn(chisq,'9.4');
   df2=putn(df,'3.');
   p2=putn(p,'pvalue.');
   ctest=c2||df2||p2;
   print ctest [label='Contrast Test Results'
         colname={'Chi-Square' '  DF' 'Pr > ChiSq'}];

   /* Make overall p-value available */
   %global pvalue;
   call symput('pvalue',p2);

quit;

%exit:
options &opts;
title; title2;
%mend;

%macro rocplot ( version, outroc=, out=, p=, id=, plottype=high, font=swissb,
                 size=2, position=F, color=black, plotchar=dot,
                 roffset=4, round=1e-8 );

%if &version ne %then %put ROCPLOT macro Version 1.0;
options nonotes;
%let nomatch=0;

/* Verify ID= is specified */
%if %quote(&id)= %then %do;
  %put ERROR: The ID= option is required.;
  %goto exit;
%end;

/* Verify P= is specified */
%if %quote(&p)= %then %do;
  %put ERROR: The P= option is required.;
  %goto exit;
%end;

/* Verify OUTROC= is specified and the data set exists */
%if %quote(&outroc) ne %then %do;
  %if %sysfunc(exist(&outroc)) ne 1 %then %do;
    %put ERROR: OUTROC= data set not found.;
    %goto exit;
  %end;
%end;
%else %do;
  %put ERROR: The OUTROC= option is required.;
  %goto exit;
%end;

/* Verify OUT= is specified and the data set exists */
%if %quote(&out) ne %then %do;
  %if %sysfunc(exist(&out)) ne 1 %then %do;
    %put ERROR: OUT= data set not found.;
    %goto exit;
  %end;
%end;
%else %do;
  %put ERROR: The OUT= option is required.;
  %goto exit;
%end;

data _outroc;
   set &outroc;
   _prob_=round(_prob_,&round);
   run;

data _out;
   set &out;
   _prob_=round(&p , &round);
   length _id $ 200;

   /* Create single label variable */
   _id=trim(left(%scan(&id,1)))
        %let i=2;
        %do %while (%scan(&id,&i) ne %str() );
   ||'/'||trim(left(%scan(&id,&i)))
          %let i=%eval(&i+1);
        %end;
   ;
   run;

proc sort data=_out nodupkey;
   by _prob_ _id;
   run;

proc sort data=_outroc nodupkey;
   by _prob_;
   run;

data _rocplot;
   _inout=0; _inroc=0;
   merge _outroc(in=_inroc) _out(in=_inout);
   by _prob_;
   if not(_inout and _inroc) then do;
     call symput('nomatch',1);
     delete;
   end;
   run;

%if &nomatch=1 %then %do;
  %put ROCPLOT: Some predicted values in OUT= did not match predicted values;
  %put %str(         in OUTROC=.  Verify that you used the ROCEPS=0 option in);
  %put %str(         PROC LOGISTIC.);
%end;

%if %upcase(%substr(&plottype,1,1))=L %then %do;
   footnote "Point labels are values of &id";
   proc plot data=_rocplot;
      plot _sensit_*_1mspec_ $ _id /
           haxis=0 to 1 by .1 vaxis=0 to 1 by .1;
      run; quit;
%end;

%if %upcase(%substr(&plottype,1,1))=H %then %do;
   data _anno;
      length function style color $ 8 position $ 1 text $ 200;
      retain function 'label' xsys ysys '2' hsys '3'
             size &size position "&position" style "&font"
             color "&color";
      set _rocplot(keep=_sensit_ _1mspec_ _id) end=eof;
      x=_1mspec_; y=_sensit_; text=trim(left(_id)); output;
     
      /* Draw (0,0) to (1,1) reference line */
      if eof then do;
        x=0; y=0; function='move'; output;
        x=1; y=1; function='draw'; line=1; hsys='1'; size=0.25; output;
      end;
      run;
     
   symbol1 i=join v=&plotchar c=blue l=1;
   footnote "Point labels are values of &id";
   axis1 offset=(1,&roffset)pct order=(0 to 1 by .1);
   proc gplot data=_rocplot;
      plot _sensit_*_1mspec_=1 / vaxis=0 to 1 by .1
                                 haxis=axis1 annotate=_anno;
      run;
      quit;
%end;

footnote;
%exit:
options notes;
%mend;


/* Define the ROC macro */
   %include "<path to your copy of the ROC macro>";
   
   /* Define the ROCPLOT macro */
   %include "<path to your copy of the ROCPLOT macro>";
   
   data roc;
     input alb tp totscore popind;
     totscore = 10 - totscore;
     datalines;
   3.0 5.8 10 0
   3.2 6.3  5 1
   3.9 6.8  3 1
   2.8 4.8  6 0
   3.2 5.8  3 1
   0.9 4.0  5 0
   2.5 5.7  8 0
   1.6 5.6  5 1
   3.8 5.7  5 1
   3.7 6.7  6 1
    .   .   6 1
   3.2 5.4  4 1
   3.8 6.6  6 1
   4.1 6.6  5 1
   3.6 5.7  5 1
   4.3 7.0  4 1
   3.6 6.7  4 0
   2.3 4.4  6 1
   4.2 7.6  4 0
   4.0 6.6  6 0
   3.5 5.8  6 1
   3.8 6.8  7 1
   3.0 4.7  8 0
   4.5 7.4  5 1
   3.7 7.4  5 1
   3.1 6.6  6 1
   4.1 8.2  6 1
   4.3 7.0  5 1
   4.3 6.5  4 1
   3.2 5.1  5 1
   2.6 4.7  6 1
   3.3 6.8  6 0
   1.7 4.0  7 0
    .   .   6 1
   3.7 6.1  5 1
   3.3 6.3  7 1
   4.2 7.7  6 1
   3.5 6.2  5 1
   2.9 5.7  9 0
   2.1 4.8  7 1
    .   .   8 1
   2.8 6.2  8 0
    .   .   7 1
    .   .   7 1
   4.0 7.0  7 1
   3.3 5.7  6 1
   3.7 6.9  5 1
   2.0  .   7 1
   3.6 6.6  5 1
   ;
   
   /* Albumin */
     title "ROC plot for Albumin";
     proc logistic data=roc;
       model popind(event='1') = alb / outroc=or roceps=0;
       output out=albpred p=palb;
       ods output association=assoc;
       run;
   
     data _null_;
        set assoc;
        if label2='c' then call symput("area",cvalue2);
        run;
   
     title2 "Approximate area under curve = &area";
     %rocplot(out=albpred, outroc=or, p=palb, id=alb)
     title2;
   
     data joint;
       set _rocplot;
       length index $ 13;
       Index='Albumin';
       run;
   
   /* Total Protein */
     title "ROC plot for Total Protein";
     proc logistic data=roc;
       model popind(event='1') = tp / outroc=or roceps=0;
       output out=tppred p=ptp;
       ods output association=assoc;
       run;
   
     data _null_;
        set assoc;
        if label2='c' then call symput("area",cvalue2);
        run;
   
     title2 "Approximate area under curve = &area";
     %rocplot(out=tppred, outroc=or, p=ptp, id=tp)
     title2;
   
     data tp;
       set _rocplot;
       length index $ 13;
       Index='Total Protein';
       run;
   
     data joint;
       set joint tp;
       run;
   
   /* K-G score */
     title "ROC plot for K-G score";
     proc logistic data=roc;
       model popind(event='1') = totscore / outroc=or roceps=0;
       output out=totspred p=ptots;
       ods output association=assoc;
       run;
   
     data _null_;
        set assoc;
        if label2='c' then call symput("area",cvalue2);
        run;
   
     title2 "Approximate area under curve = &area";
     %rocplot(out=totspred, outroc=or, p=ptots, id=totscore)
     title2;
   
     data kg;
       set _rocplot;
       length index $ 13;
       Index='K-G Score';
       run;
   
     data joint;
       set joint kg;
       run;
   
   /* Compare areas under the ROC curves of the indices using the method presented
      in DeLong, et. al. (1988).
   */
     %roc(data=albpred tppred totspred,
          var=palb ptp ptots,
          response=popind)
   
   /* Plot all indices and p-value of overall test comparing areas */
     symbol1 i=join v=circle c=blue line=33;
     symbol2 i=join v=dot c=green line=1;
     symbol3 i=join v=triangle c=red line=4;
   
     proc gplot data=joint;
       title  "Post-Op Indices of surgical success";
       title2 "Test of H0: equal areas under curves -- p=&pvalue";
       footnote "From DeLong, et. al. (1988, Biometrics 44)";
       label index="Index";
       plot _sensit_ * _1mspec_ = Index /
          vaxis=0 to 1 by .1 haxis=0 to 1 by .1;
       run;
       quit;
     title;
     title2;
     footnote;

Hors ligne

 

#5 16-09-2007 14:24:48

alaa-eddine
Member
Date d'inscription: 07-03-2007
Messages: 398

Re: pourquoi ne puis je pas poster???

Mais qu'est ce que c'est que ce truc de Oufs yikes ???!!!
lool je pense qu'il doit y avoir plus simple...

Hors ligne

 

#6 17-09-2007 12:00:47

esa_sr
Administrator
Date d'inscription: 21-02-2007
Messages: 5795
Site web

Re: pourquoi ne puis je pas poster???

au travail alaa-eddine !
voyons voir si vous saurez me simplifier ce programme !

stat_sas, merci de nous avoir proposé votre programme, ne faites pas attention aux commentaires d'alaa-eddine, il est jaloux -

sinon, il ne me semble pas que vous soyez un étudiant de chez nous, vous avez préparé quel diplôme ? 

cordialement

SR

Hors ligne

 

#7 18-09-2007 21:53:13

alaa-eddine
Member
Date d'inscription: 07-03-2007
Messages: 398

Re: pourquoi ne puis je pas poster???

esa_sr a écrit:

ne faites pas attention aux commentaires d'alaa-eddine, il est jaloux -

yikes Me ?!! jealous ?! Nooo ! lol

Bon j'ai bidouillé une ptite version simplifiée qui permet de comparer non seulement; 2 ;mais plusieurs Roc Curve en même temps ! big_smile

Le principe est simple : je calcul les « area » sous les courbes roc puis je les « imprime », le modèle le plus fiable est en effet celui qui possède la plus grande valeur de l'aire sous la courbe !

Quelques explications sur le paramétrage de la macro :

Code:

%roc (in=score1,test=P_1,crit=incident,snbr=1,dis=1,out=tst_1);

in : ici je rentre le nom de la base où figurent toutes mes données.

test : ici je rentre la proba estimée par mon modèle logit ou probit...

crit : je rentre la variable expliquée ( l'événement à modéliser )

snbr : ça c'est pour numéroter les bases en sortie, pour ne pas qu'elles se confondent ( 1 pour la roc issue de la base 1 , 2 pour la roc issue de la base 2 ..etc b). utile par la suite pour les PROC APPEND.

dis=1 : faut toujours laisser ce paramètre = à 1, je m'en sert pour calculer les fréquences !!

out : beh out.. lol

Let's Go !!

Code:

%macro roc(in=,test=,crit=,dis=1,snbr=,out=);

* prelim ;

data _&test; set &in;
    if (&crit ne . and &test ne .); 
    keep &test &crit;

* calcul des frequences ;

proc freq data=_&test;
    table &crit / noprint out=_&crit;

data _&crit; set _&crit end=eof; 
    if (&crit eq &dis) then nryes = COUNT; 
    else nrno = COUNT; 
    if (eof) then output; 
    retain nryes nrno ; 
    keep nryes nrno ;

proc freq data=_&test; 
    tables &test*&crit / noprint out=_table;

data &out; set _table; 
    by &test;
    if (first.&test) then do; 
    county=0; 
    countn=0; 
    end;

    if (_N_ eq 1) then do; 
    set _&crit; 
    sens = nryes; 
    spec = 0; 
    lastspec= spec; 
    x = 0; 
    output; 
    end;

    x = &test; 
    if (&crit eq &dis) then do; 
    county= count; 
    sens = sens-count; 
    end; 
    else do; 
    lastspec=spec; 
    countn= count; 
    spec = spec+count; 
    end; 
    if (last.&test) then do; 
    stat=countn*sens + ((county*countn)/2); 
    q1 =county*((lastspec**2)+(lastspec*countn)+(countn**2)/3); 
    q2 =countn*((sens**2)+(sens*county)+(county**2)/3); 
    output; 
    end;

    retain sens spec lastspec county countn; 
    keep x sens spec stat q1 q2 county countn;

* calcul aire sous la courbe;

proc summary; 
    var stat q1 q2; 
    output out=area_&snbr sum=stat q1 q2; 

    data area_&snbr; set area_&snbr; 
    if (_N_ eq 1) then set _&crit; 
    stat=stat/(nryes*nrno ); 
    q1 =q1 /(nryes*nrno **2); 
    q2 =q2 /(nryes**2*nrno ); 
    sd =stat*(1-stat) + (nryes - 1) *(q1-stat**2) + (nrno - 1)*(q2-stat**2) ; 
    area = stat; sd = sqrt(sd); 
    se = sd/sqrt(nryes*nrno); 
    zstat= (area-.5)/sd;
    numero=&snbr ; 
    label area ="Aire sous la ROC"; 
    label se ="ecart-type Air";
    label numero =" idetifient base"; 
    keep area se sd q1 q2 numero; 

%mend;

Maintenant que ma macro est prête je vais l'appliquer à chaque base (pour cet exemple je vais comparer 4 roc curve):

Code:

%roc (in=score1,test=P_1,crit=incident,snbr=1,dis=1,out=tst_1); 
%roc (in=score2,test=P_1,crit=incident,snbr=2,dis=1,out=tst_2);
%roc (in=score3,test=P_1,crit=incident,snbr=3,dis=1,out=tst_3);
%roc (in=score4,test=P_1,crit=incident,snbr=4,dis=1,out=tst_4);

Ce qui me donne 4 bases pour chaque Roc, qu'il va falloir ramasser dans un seul fichier pour la PROC PRINT

Code:

%macro ramasse(n=);
data ensemble; set area_1;run;
%do i=2 %to &n ;
proc append base=ensemble new=area_&i ; run;
%end;
proc print data= ensemble label noobs;
var area se numero;
run;
%mend;

%ramasse(n=4);

petit detail : n est le nombre de Roc à comparer.

Et voici la sortie :

                                    Aire
                                  sous la     ecart-      idetifient
                                    ROC      type Air        base

                                  0.66180    0.027414         1
                                  0.66533    0.027346         2
                                  0.56550    0.029624         3
                                  0.51023    0.028485         4


Le modéle le plus fiable est donc le modèle issu de la base numero 2 big_smile

voili voilou

Hors ligne

 

#8 19-09-2007 06:43:58

gang
Member
Lieu: Orleans
Date d'inscription: 05-03-2007
Messages: 324

Re: pourquoi ne puis je pas poster???

esa_sr  a écrit:

au travail alaa-eddine !
voyons voir si vous saurez me simplifier ce programme !.

et bah kelle reactivité mr eddine ; alors Mr s.R qu'en dites vous lol ....

Hors ligne

 

#9 19-09-2007 14:20:09

20syl
Member
Lieu: Orléans
Date d'inscription: 05-03-2007
Messages: 117

Re: pourquoi ne puis je pas poster???

moui vous vous embétez quand meme pour rien dites big_smile

il me semble que SAS la calcule de lui même l'aire en question big_smile

sinon une petite approximation sous excel ca se fait tout seul il suffit juste de récupérer la PD ( proba de défaut) m'enfin ca nécessite de couper en classes de risques quand même et de calculer la réparition de la population  dans chaque classe ...

Dernière modification par 20syl (19-09-2007 14:21:21)

Hors ligne

 

#10 19-09-2007 15:22:42

alaa-eddine
Member
Date d'inscription: 07-03-2007
Messages: 398

Re: pourquoi ne puis je pas poster???

20syl a écrit:

il me semble que SAS la calcule de lui même l'aire en question big_smile

Ahh non ! ça c'est qu'une options dans la PROC LOGISTIC uniquement, ( enfin je crois...) "outroc", ou sinon le "c=" dans la sortie de la PROC!

Par contre quand t'as un logit ou probit bizzaaard ( Probit Spatial.. big_smile ) que tu peux pas estimer avec une PROC LOGISTIC du fait de l'écriture du modèle et que la méthode par défaut utilisée est le Max de Vraisemblance.. alors que toi t'as envie d'utiliser la GMM par exemple, là t'es embêté ! ( et oui.. j'en ai bavé neutral )

il faut donc tout faire toi même y compris la ROC et - comme "STAT_SAS" nous l'a rappelé - : la comparaison de plusieurs ROC big_smile

P.S : je vois que t'as fais une grosse descente sur le forum, y a du 20syl partout, t'as retourné toutes les tables, mis la musique à block, insulter les vigiles... lol, molo hein !

Hors ligne

 

#11 19-09-2007 15:49:52

gang
Member
Lieu: Orleans
Date d'inscription: 05-03-2007
Messages: 324

Re: pourquoi ne puis je pas poster???

yep il ns a envahit le berrichon
yep 20syl t as vu nos prouesses hier 2-0 pour l'om vlam

Hors ligne

 

#12 19-09-2007 16:31:09

alaa-eddine
Member
Date d'inscription: 07-03-2007
Messages: 398

Re: pourquoi ne puis je pas poster???

D'ailleurs en parlant d'Excel... qui c'est qui pourra m'expliquer comment ça marche un de ces 4 ?...je sais pas faire grand chose avec hmm !

y a pas que SAS dans la vie ^^

Hors ligne

 

#13 19-09-2007 20:38:42

gang
Member
Lieu: Orleans
Date d'inscription: 05-03-2007
Messages: 324

Re: pourquoi ne puis je pas poster???

alaa-eddine a écrit:

D'ailleurs en parlant d'Excel... qui c'est qui pourra m'expliquer comment ça marche un de ces 4 ?...je sais pas faire grand chose avec hmm !

y a pas que SAS dans la vie ^^

yep y a pas que sas dans la vie et de plus excel comment les gens s'en servent dans les boite c'est hallucinant et on en fait plein de choses mais je pense que tu l apprends sur le tas lol

Hors ligne

 

#14 19-09-2007 21:35:38

alaa-eddine
Member
Date d'inscription: 07-03-2007
Messages: 398

Re: pourquoi ne puis je pas poster???

gang a écrit:

comment les gens s'en servent dans les boite c'est hallucinant et on en fait plein de choses

Yep ! j'ai vu ça cet été et l'année dernière en Recherche opérationnelle hmm !

Au pire...

gang a écrit:

mais je pense que tu l apprends sur le tas lol

smile

Hors ligne

 

#15 20-09-2007 10:24:20

20syl
Member
Lieu: Orléans
Date d'inscription: 05-03-2007
Messages: 117

Re: pourquoi ne puis je pas poster???

ben perso je l'ai appris sur le tas moi (tableau dynamique, recherchev,...)

Hors ligne

 

Pied de page des forums

Powered by PunBB
© Copyright 2002–2005 Rickard Andersson

[ Generated in 0.011 seconds, 8 queries executed ]